From 4d843a5e03c91867614c94829c5255bc067a90c6 Mon Sep 17 00:00:00 2001
From: Nathan Lee <me@nwlee.tech>
Date: Thu, 11 Jun 2026 11:14:40 -0500
Subject: initial commit

---
 linker.ld | 65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 linker.ld

(limited to 'linker.ld')

diff --git a/linker.ld b/linker.ld
new file mode 100644
index 0000000..4f86e10
--- /dev/null
+++ b/linker.ld
@@ -0,0 +1,65 @@
+OUTPUT_ARCH(riscv)
+ENTRY(_start)
+
+MEMORY
+{
+    ROM   (rx)  : ORIGIN = 0x80000000, LENGTH = 1M
+    RAM   (rwx) : ORIGIN = 0x80400000, LENGTH = 1M
+}
+
+SECTIONS
+{
+    .text : {
+        KEEP(*(.text._start))
+        KEEP(*(.text.start))
+        *(.text)
+        *(.text.*)
+    } > ROM
+
+    .rodata : {
+        *(.rodata)
+        *(.rodata.*)
+    } > ROM
+
+    .init_array : {
+        __init_array_start = .;
+        KEEP(*(.init_array))
+        KEEP(*(.init_array.*))
+        __init_array_end = .;
+    } > ROM
+
+    .data : {
+        __data_start = .;
+        *(.data)
+        *(.data.*)
+        __data_end = .;
+    } > RAM AT> ROM
+    __data_load = LOADADDR(.data);
+
+    .bss : {
+        __bss_start = .;
+        *(.bss)
+        *(.bss.*)
+        *(COMMON)
+        __bss_end = .;
+    } > RAM
+
+    .stack (NOLOAD) : {
+        . = ALIGN(16);
+        __stack_bottom = .;
+        . += 8K;
+        __stack_top = .;
+    } > RAM
+
+    /DISCARD/ : {
+        *(.eh_frame)
+        *(.eh_frame.*)
+        *(.eh_frame_hdr)
+        *(.comment)
+        *(.note.*)
+        *(.debug_*)
+        *(.stab*)
+        *(.llvm_*)
+        *(.rela.*)
+    }
+}
-- 
cgit v1.2.3